***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 17, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt SM5S36A-AU A K 
.param
+vc0 = 1.306e-10	vc1 = 1.306e-10		vc2 = 1.000		vc3 = 4.135e-11		vc4 = 1.782e-1
+tc1 = 5.721e-2		tc2 = 2.721e-2		tc3 = 3.001e-2		tc4 = 2.351e-2
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 9.208e-13	   n = 1.079		  rs = 4.002e-3
+ibv = 5.0e-3		 nbv = 1.0		  bv = 42.1
+ikf = 1.055e-0
***** capacitance parameter *****
+cjo = 4.821e-9		   m = 3.347e-1		  vj = 5.736e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.082		 xti = 3
+trs1 = -5.225e-4	trs2 = 1.375e-5		tikf = 2.0e-3
+tbv1 = 8.652e-4	tbv2 = -7.637e-7	
.ends SM5S36A-AU
*$
